Files for Webinar: A POST26 Primer

Categories:

We just finished our webinar for 4/12/2012 on the basics of the POST26 Time History Post Processor.  As promised, here are the files used for examples in the webinar, as well as the PowerPoint:

Tower-of-Test (ToT) test model, APDL:

! Build basic 2x2x60 tower
finish
/clear
/prep7
blc4,-1,-1,2,2,60
et,1,185
mptemp,1,70
mpdata,ex,1,1,20e6
mpdata,nuxy,1,1,.23
mpdata,dens,1,1,.001
alphad,5

!Mesh
esize,.9
vmesh,all
/view,1,1,1,1
/vup,1,z
eplot

!create component of bottom nodes
nsel,s,loc,z,0
cm,nbt,node
nsel,all

!Fix in UY and UZ, move UX 1" in first time step
d,nbt,uy,0
d,nbt,uz,0
d,nbt,ux,1
time,.1

! Set up Transient, Large Deflection Run
antype,4
trnopt,full
lumpm,0
nlgeom,1
kbc,0
timint,1
nsubst,40,40,40
outres,all,1
!Save first Load Step
lswrite,1

!LS 2, UX = 5 inches
d,nbt,ux,5
time,.2
lswrite,2

!LS 3, UX = 0 inches
d,nbt,ux,0
time,.3
lswrite,3

!LS 3, no change, let it damp out
time,2
lswrite,4

! Solve all four load steps
/solu
lssolve ,1,4
finish

! Enter POST26
/POST26
NUMVAR,200    ! Max out number of allowed variables
!SOLU,191,NCMIT
!STORE,MERGE
!FILLDATA,191,,,,1,1
!REALVAR,191,191
!!*
! Get UX on node 18
NSOL,2,18,U,X, UX_2
STORE,MERGE
!plot UX results
XVAR,1
PLVAR,2

! Calculate total force on node 8 (sqrt-sum-of-squares)
! Put reaction forces in each direction in a variable (11-13)
rforce,11,8,f,x,FX_8
rforce,12,8,f,y,FY_8
rforce,13,8,f,z,FZ_8
! Square the variables
prod,14,11,11
prod,15,12,12
prod,16,13,13
! Add them together
add,17,14,15,16
! Square Root
sqrt,18,17
! Plot the result
plvar,18

! No find max stress on "edge" at 1,1
! Grab the nodes
nsel,s,loc,x,1
nsel,r,loc,y,-1
! Get the node count
*get,nnd,node,,count
! Get first node in selected set
nn = ndnext(-1)
! Store its SIG1 values in var 20
ansol,20,nn,s,1
! Get next node
nn = ndnext(nn)
!loop on remaining nodes
*do,i,1,nnd-1
    !Put SIG1 of current node in var 21
    ansol,21,nn,s,1
    ! Compare 20 and 21, and at each time step, but the larger value in 20
    large,20,20,21
    ! Move on to the next node
    nn = ndnext(nn)
*enddo
! Plot the max values
plvar,20
! Use *get to get the maximum value over time, and when that time is
*get,mxs,vari,20,extrem,vmax
*get,mxt,vari,20,extrem,tmax
! Select all the nodes
nsel,all


 /eof
 PLNSOL, U,SUM, 2,1.0
 ANTIME,80,0.25, ,1,2,0,1

 data,20,,,,ld_1,0
 (F,F)

Tower-of-Test (ToT) test model, ANSYS Mechanical with APDL Snippets:

PowerPoint Presentation:

Categories

Get Your Ansys Products & Support from the Engineers who Contribute to this Blog.

Technical Expertise to Enable your Additive Manufacturing Success.

PADT’s Pulse Newsletter

Keep up to date on what is going on at PADT by subscribing to our newsletter.


By submitting this form, you are consenting to receive marketing emails from: . You can revoke your consent to receive emails at any time by using the SafeUnsubscribe® link, found at the bottom of every email. Emails are serviced by Constant Contact

Share this post:

Upcoming Events

03/27/2024

2024 Arizona Space Summit

03/28/2024

SAF Blue Carpet Event

03/28/2024

2024 Arizona Space Summit

04/03/2024

Low Frequency Updates in Ansys 2024 R1 - Webinar

04/03/2024

Venture Madness Conference Reception + Expo

04/03/2024

Stratasys F3300: Game Changing Throughput - Webinar

04/08/2024

39th Space Symposium

04/09/2024

39th Space Symposium

04/10/2024

Discovery Updates in Ansys 2024 R1 - Webinar

04/10/2024

39th Space Symposium

04/11/2024

39th Space Symposium

04/22/2024

Experience Stratasys Truck Tour: Houston, TX

04/24/2024

Structures Updates in Ansys 2024 R1 (2)

04/24/2024

Experience Stratasys Truck Tour: Houston, TX

05/07/2024

Experience Stratasys Truck Tour: Albuquerque, NM

05/08/2024

Fluent Materials Processing Updates in Ansys 2024 R1 - Webinar

05/09/2024

Experience Stratasys Truck Tour: Los Alamos, NM

05/14/2024

Simulation World 2024

05/15/2024

Simulation World 2024

05/16/2024

Simulation World 2024

05/22/2024

Optics Updates in Ansys 2024 R1 - Webinar

06/12/2024

Connect Updates in Ansys 2024 R1 - Webinar

06/26/2024

Structures Updates in Ansys 2024 R1 (3) - Webinar

06/27/2024

E-Mobility and Clean Energy Summit

07/10/2024

Fluids Updates in Ansys 2024 R1 - Webinar

08/05/2024

2024 CEO Leadership Retreat

10/23/2024

PADT30 | Nerdtoberfest 2024

Search in PADT site

Contact Us

Most of our customers receive their support over the phone or via email. Customers who are close by can also set up a face-to-face appointment with one of our engineers.

For most locations, simply contact us: